Math::BigRat(3)

NAME
Math::BigRat - arbitrary size rational number math package

SYNOPSIS
  use Math::BigRat;

  # Generic constructor method (always returns a new object)

  $x = Math::BigRat->new($str);             # defaults to 0
  $x = Math::BigRat->new('256');            # from decimal
  $x = Math::BigRat->new('0256');           # from decimal
  $x = Math::BigRat->new('0xcafe');         # from hexadecimal
  $x = Math::BigRat->new('0x1.fap+7');      # from hexadecimal
  $x = Math::BigRat->new('0o377');          # from octal
  $x = Math::BigRat->new('0o1.35p+6');      # from octal
  $x = Math::BigRat->new('0b101');          # from binary
  $x = Math::BigRat->new('0b1.101p+3');     # from binary

  # Specific constructor methods (no prefix needed; when used as
  # instance method, the value is assigned to the invocand)

  $x = Math::BigRat->from_dec('234');       # from decimal
  $x = Math::BigRat->from_hex('cafe');      # from hexadecimal
  $x = Math::BigRat->from_hex('1.fap+7');   # from hexadecimal
  $x = Math::BigRat->from_oct('377');       # from octal
  $x = Math::BigRat->from_oct('1.35p+6');   # from octal
  $x = Math::BigRat->from_bin('1101');      # from binary
  $x = Math::BigRat->from_bin('1.101p+3');  # from binary
  $x = Math::BigRat->from_bytes($bytes);    # from byte string
  $x = Math::BigRat->from_base('why', 36);  # from any base
  $x = Math::BigRat->from_base_num([1, 0], 2);  # from any base
  $x = Math::BigRat->from_ieee754($b, $fmt);    # from IEEE-754 bytes
  $x = Math::BigRat->from_fp80($b);         # from x86 80-bit
  $x = Math::BigRat->bzero();               # create a +0
  $x = Math::BigRat->bone();                # create a +1
  $x = Math::BigRat->bone('-');             # create a -1
  $x = Math::BigRat->binf();                # create a +inf
  $x = Math::BigRat->binf('-');             # create a -inf
  $x = Math::BigRat->bnan();                # create a Not-A-Number
  $x = Math::BigRat->bpi();                 # returns pi

  $y = $x->copy();        # make a copy (unlike $y = $x)
  $y = $x->as_int();      # return as a Math::BigInt
  $y = $x->as_float();    # return as a Math::BigFloat
  $y = $x->as_rat();      # return as a Math::BigRat

  # Boolean methods (these don't modify the invocand)

  $x->is_zero();          # true if $x is 0
  $x->is_one();           # true if $x is +1
  $x->is_one("+");        # true if $x is +1
  $x->is_one("-");        # true if $x is -1
  $x->is_inf();           # true if $x is +inf or -inf
  $x->is_inf("+");        # true if $x is +inf
  $x->is_inf("-");        # true if $x is -inf
  $x->is_nan();           # true if $x is NaN

  $x->is_finite();        # true if -inf < $x < inf
  $x->is_positive();      # true if $x > 0
  $x->is_pos();           # true if $x > 0
  $x->is_negative();      # true if $x < 0
  $x->is_neg();           # true if $x < 0
  $x->is_non_positive()   # true if $x <= 0
  $x->is_non_negative()   # true if $x >= 0

  $x->is_odd();           # true if $x is odd
  $x->is_even();          # true if $x is even
  $x->is_int();           # true if $x is an integer

  # Comparison methods (these don't modify the invocand)

  $x->bcmp($y);           # compare numbers (undef, < 0, == 0, > 0)
  $x->bacmp($y);          # compare abs values (undef, < 0, == 0, > 0)
  $x->beq($y);            # true if $x == $y
  $x->bne($y);            # true if $x != $y
  $x->blt($y);            # true if $x < $y
  $x->ble($y);            # true if $x <= $y
  $x->bgt($y);            # true if $x > $y
  $x->bge($y);            # true if $x >= $y

  # Arithmetic methods (these modify the invocand)

  $x->bneg();             # negation
  $x->babs();             # absolute value
  $x->bsgn();             # sign function (-1, 0, 1, or NaN)
  $x->bdigitsum();        # sum of decimal digits
  $x->binc();             # increment $x by 1
  $x->bdec();             # decrement $x by 1
  $x->badd($y);           # addition (add $y to $x)
  $x->bsub($y);           # subtraction (subtract $y from $x)
  $x->bmul($y);           # multiplication (multiply $x by $y)
  $x->bmuladd($y, $z);    # $x = $x * $y + $z
  $x->bdiv($y);           # division (floored)
  $x->bmod($y);           # modulus (x % y)
  $x->bmodinv($mod);      # modular multiplicative inverse
  $x->bmodpow($y, $mod);  # modular exponentiation (($x ** $y) % $mod)
  $x->btdiv($y);          # division (truncated), set $x to quotient
  $x->btmod($y);          # modulus (truncated)
  $x->binv()              # inverse (1/$x)
  $x->bpow($y);           # power of arguments (x ** y)
  $x->blog();             # logarithm of $x to base e (Euler's number)
  $x->blog($base);        # logarithm of $x to base $base (e.g., base 2)
  $x->bexp();             # calculate e ** $x where e is Euler's number
  $x->bilog2();           # log2($x) rounded down to nearest int
  $x->bilog10();          # log10($x) rounded down to nearest int
  $x->bclog2();           # log2($x) rounded up to nearest int
  $x->bclog10();          # log10($x) rounded up to nearest int
  $x->bnok($y);           # combinations (binomial coefficient n over k)
  $x->bperm($y);          # permutations
  $x->buparrow($n, $y);   # Knuth's up-arrow notation
  $x->bhyperop($n, $y);   # n'th hyperoprator
  $x->backermann($y);     # the Ackermann function
  $x->bsin();             # sine
  $x->bcos();             # cosine
  $x->batan();            # inverse tangent
  $x->batan2($y);         # two-argument inverse tangent
  $x->bsqrt();            # calculate square root
  $x->broot($y);          # $y'th root of $x (e.g. $y == 3 => cubic root)
  $x->bfac();             # factorial of $x (1*2*3*4*..$x)
  $x->bdfac();            # double factorial of $x ($x*($x-2)*($x-4)*...)
  $x->btfac();            # triple factorial of $x ($x*($x-3)*($x-6)*...)
  $x->bmfac($k);          # $k'th multi-factorial of $x ($x*($x-$k)*...)
  $x->bfib($k);           # $k'th Fibonacci number
  $x->blucas($k);         # $k'th Lucas number

  $x->blsft($n);          # left shift $n places in base 2
  $x->blsft($n, $b);      # left shift $n places in base $b
  $x->brsft($n);          # right shift $n places in base 2
  $x->brsft($n, $b);      # right shift $n places in base $b

  # Bitwise methods (these modify the invocand)

  $x->bblsft($y);         # bitwise left shift
  $x->bbrsft($y);         # bitwise right shift
  $x->band($y);           # bitwise and
  $x->bior($y);           # bitwise inclusive or
  $x->bxor($y);           # bitwise exclusive or
  $x->bnot();             # bitwise not (two's complement)

  # Rounding methods (these modify the invocand)

  $x->round($A, $P, $R);  # round to accuracy or precision using
                          #   rounding mode $R
  $x->bround($n);         # accuracy: preserve $n digits
  $x->bfround($n);        # $n > 0: round to $nth digit left of dec. point
                          # $n < 0: round to $nth digit right of dec. point
  $x->bfloor();           # round towards minus infinity
  $x->bceil();            # round towards plus infinity
  $x->bint();             # round towards zero

  # Other mathematical methods (these don't modify the invocand)

  $x->bgcd($y);           # greatest common divisor
  $x->blcm($y);           # least common multiple

  # Object property methods (these don't modify the invocand)

  $x->sign();             # the sign, either +, - or NaN
  $x->digit($n);          # the nth digit, counting from the right
  $x->digit(-$n);         # the nth digit, counting from the left
  $x->digitsum();         # sum of decimal digits
  $x->length();           # return number of digits in number
  $x->mantissa();         # return (signed) mantissa as a Math::BigInt
  $x->exponent();         # return exponent as a Math::BigInt
  $x->parts();            # return (mantissa,exponent) as a Math::BigInt
  $x->sparts();           # mantissa and exponent (as integers)
  $x->nparts();           # mantissa and exponent (normalised)
  $x->eparts();           # mantissa and exponent (engineering notation)
  $x->dparts();           # integer and fraction part
  $x->fparts();           # numerator and denominator
  $x->numerator();        # numerator
  $x->denominator();      # denominator

  # Conversion methods (these don't modify the invocand)

  $x->bstr();             # decimal notation (possibly zero padded)
  $x->bnstr();            # string in normalized notation
  $x->bestr();            # string in engineering notation
  $x->bdstr();            # string in decimal notation (no padding)
  $x->bfstr();            # string in fractional notation

  $x->to_hex();           # as signed hexadecimal string
  $x->to_bin();           # as signed binary string
  $x->to_oct();           # as signed octal string
  $x->to_bytes();         # as byte string
  $x->to_base($b);        # as string in any base
  $x->to_base_num($b);    # as array of integers in any base
  $x->to_ieee754($fmt);   # to bytes encoded according to IEEE 754-2008
  $x->to_fp80();          # encode value in x86 80-bit format

  $x->as_hex();           # as signed hexadecimal string with "0x" prefix
  $x->as_bin();           # as signed binary string with "0b" prefix
  $x->as_oct();           # as signed octal string with "0" prefix

  # Other conversion methods (these don't modify the invocand)

  $x->numify();           # return as scalar (might overflow or underflow)

DESCRIPTION
Math::BigRat complements Math::BigInt and Math::BigFloat by providing support for arbitrary big rational numbers.

  Math Library
You can change the underlying module that does the low-level math operations by using:

    use Math::BigRat try => 'GMP';

Note: This needs Math::BigInt::GMP installed.

The following would first try to find Math::BigInt::Foo, then Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:

    use Math::BigRat try => 'Foo,Math::BigInt::Bar';

If you want to get warned when the fallback occurs, replace "try" with "lib":

    use Math::BigRat lib => 'Foo,Math::BigInt::Bar';

If you want the code to die instead, replace "try" with "only":

    use Math::BigRat only => 'Foo,Math::BigInt::Bar';

METHODS
Any methods not listed here are derived from Math::BigFloat (or Math::BigInt), so make sure you check these two modules for further information.

new()
        $x = Math::BigRat->new('1/3');

    Create a new Math::BigRat object. Input can come in various forms:

        $x = Math::BigRat->new(123);                            # scalars
        $x = Math::BigRat->new('inf');                          # infinity
        $x = Math::BigRat->new('123.3');                        # float
        $x = Math::BigRat->new('1/3');                          # simple string
        $x = Math::BigRat->new('1 / 3');                        # spaced
        $x = Math::BigRat->new('1 / 0.1');                      # w/ floats
        $x = Math::BigRat->new(Math::BigInt->new(3));           # BigInt
        $x = Math::BigRat->new(Math::BigFloat->new('3.1'));     # BigFloat
        $x = Math::BigRat->new(Math::BigInt::Lite->new('2'));   # BigLite

        # You can also give D and N as different objects:
        $x = Math::BigRat->new(
                Math::BigInt->new(-123),
                Math::BigInt->new(7),
             );                      # => -123/7

from_dec()
        my $h = Math::BigRat->from_dec("1.2");

    Create a BigRat from a decimal number in string form. It is equivalent to "new()", but does not accept anything but strings representing finite, decimal numbers.

from_hex()
        my $h = Math::BigRat->from_hex("0x10");

    Create a BigRat from a hexadecimal number in string form.

from_oct()
        my $o = Math::BigRat->from_oct("020");

    Create a BigRat from an octal number in string form.

from_bin()
        my $b = Math::BigRat->from_bin("0b10000000");

    Create a BigRat from an binary number in string form.

from_bytes()
        $x = Math::BigRat->from_bytes("\xf3\x6b");  # $x = 62315

    Interpret the input as a byte string, assuming big endian byte order. The output is always a non-negative, finite integer.

    See "from_bytes()" in Math::BigInt.

from_ieee754()
        # set $x to 13176795/4194304, the closest value to pi that can be
        # represented in the binary32 (single) format
        $x = Math::BigRat -> from_ieee754("40490fdb", "binary32");

    Interpret the input as a value encoded as described in IEEE754-2008.

    See "from_ieee754()" in Math::BigFloat.

from_fp80()
        # set $x to 14488038916154245685/4611686018427387904, the closest value
        # to pi that can be represented in the x86 80-bit format
        $x = Math::BigRat -> from_fp80("4000c90fdaa22168c235");

    Interpret the input as a value encoded in the x86 extended-precision 80-bit format.

    See "from_fp80()" in Math::BigFloat.

from_base()
    See "from_base()" in Math::BigInt.

bzero()
        $x = Math::BigRat->bzero();

    Creates a new BigRat object representing zero. If used on an object, it will set it to zero:

        $x->bzero();

bone()
        $x = Math::BigRat->bone($sign);

    Creates a new BigRat object representing one. The optional argument is either '-' or '+', indicating whether you want one or minus one. If used on an object, it will set it to one:

        $x->bone();                 # +1
        $x->bone('-');              # -1

binf()
        $x = Math::BigRat->binf($sign);

    Creates a new BigRat object representing infinity. The optional argument is either '-' or '+', indicating whether you want infinity or minus infinity. If used on an object, it will set it to infinity:

        $x->binf();
        $x->binf('-');

bnan()
        $x = Math::BigRat->bnan();

    Creates a new BigRat object representing NaN (Not A Number). If used on an object, it will set it to NaN:

        $x->bnan();

bpi()
        $x = Math::BigRat -> bpi();         # default accuracy
        $x = Math::BigRat -> bpi(7);        # specified accuracy

    Returns a rational approximation of PI accurate to the specified accuracy or the default accuracy if no accuracy is specified. If called as an instance method, the value is assigned to the invocand.

        $x = Math::BigRat -> bpi(1);        # returns "3"
        $x = Math::BigRat -> bpi(3);        # returns "22/7"
        $x = Math::BigRat -> bpi(7);        # returns "355/113"

copy()
        my $z = $x->copy();

    Makes a deep copy of the object.

    Please see the documentation in Math::BigInt for further details.

as_int()
        $y = $x -> as_int();        # $y is a Math::BigInt

    Returns $x as a Math::BigInt object regardless of upgrading and downgrading. If $x is finite, but not an integer, $x is truncated.

as_rat()
        $y = $x -> as_rat();        # $y is a Math::BigRat

    Returns $x a Math::BigRat object regardless of upgrading and downgrading. The invocand is not modified.

as_float()
        $x = Math::BigRat->new('13/7');
        print $x->as_float(), "\n";             # '1'

        $x = Math::BigRat->new('2/3');
        print $x->as_float(5), "\n";            # '0.66667'

    Returns a copy of the object as Math::BigFloat object regardless of upgrading and downgrading, preserving the accuracy as wanted, or the default of 40 digits.

bround()/round()/bfround()
    Are not yet implemented.

is_zero()
        print "$x is 0\n" if $x->is_zero();

    Return true if $x is exactly zero, otherwise false.

is_one()
        print "$x is 1\n" if $x->is_one();

    Return true if $x is exactly one, otherwise false.

is_finite()
        $x->is_finite();    # true if $x is not +inf, -inf or NaN

    Returns true if the invocand is a finite number, i.e., it is neither +inf, -inf, nor NaN.

is_positive()
is_pos()
        print "$x is >= 0\n" if $x->is_positive();

    Return true if $x is positive (greater than or equal to zero), otherwise false. Please note that '+inf' is also positive, while 'NaN' and '-inf' aren't.

    "is_positive()" is an alias for "is_pos()".

is_negative()
is_neg()
        print "$x is < 0\n" if $x->is_negative();

    Return true if $x is negative (smaller than zero), otherwise false. Please note that '-inf' is also negative, while 'NaN' and '+inf' aren't.

    "is_negative()" is an alias for "is_neg()".

is_odd()
        print "$x is odd\n" if $x->is_odd();

    Return true if $x is odd, otherwise false.

is_even()
        print "$x is even\n" if $x->is_even();

    Return true if $x is even, otherwise false.

is_int()
        print "$x is an integer\n" if $x->is_int();

    Return true if $x has a denominator of 1 (e.g. no fraction parts), otherwise false. Please note that '-inf', 'inf' and 'NaN' aren't integer.

  Comparison methods
None of these methods modify the invocand object. Note that a "NaN" is neither less than, greater than, or equal to anything else, even a "NaN".

bcmp()
        $x->bcmp($y);

    Compares $x with $y and takes the sign into account. Returns -1, 0, 1 or undef.

bacmp()
        $x->bacmp($y);

    Compares $x with $y while ignoring their sign. Returns -1, 0, 1 or undef.

beq()
        $x -> beq($y);

    Returns true if and only if $x is equal to $y, and false otherwise.

bne()
        $x -> bne($y);

    Returns true if and only if $x is not equal to $y, and false otherwise.

blt()
        $x -> blt($y);

    Returns true if and only if $x is equal to $y, and false otherwise.

ble()
        $x -> ble($y);

    Returns true if and only if $x is less than or equal to $y, and false otherwise.

bgt()
        $x -> bgt($y);

    Returns true if and only if $x is greater than $y, and false otherwise.

bge()
        $x -> bge($y);

    Returns true if and only if $x is greater than or equal to $y, and false otherwise.

blsft()/brsft()
    Used to shift numbers left/right.

    Please see the documentation in Math::BigInt for further details.

bneg()
        $x->bneg();

    Used to negate the object in-place.

bnorm()
        $x->bnorm();

    Reduce the number to the shortest form. This routine is called automatically whenever it is needed.

binc()
        $x->binc();

    Increments $x by 1 and returns the result.

bdec()
        $x->bdec();

    Decrements $x by 1 and returns the result.

badd()
        $x->badd($y);

    Adds $y to $x and returns the result.

bsub()
        $x->bsub($y);

    Subtracts $y from $x and returns the result.

bmul()
        $x->bmul($y);

    Multiplies $y to $x and returns the result.

bdiv()
        $q = $x->bdiv($y);
        ($q, $r) = $x->bdiv($y);

    In scalar context, divides $x by $y and returns the result. In list context, does floored division (F-division), returning an integer $q and a remainder $r so that $x = $q * $y + $r. The remainer (modulo) is equal to what is returned by "$x->bmod($y)".

bmod()
        $x->bmod($y);

    Returns $x modulo $y. When $x is finite, and $y is finite and non-zero, the result is identical to the remainder after floored division (F-division). If, in addition, both $x and $y are integers, the result is identical to the result from Perl's % operator.

binv()
        $x->binv();

    Inverse of $x.

bsqrt()
        $x->bsqrt();

    Calculate the square root of $x.

bpow()
        $x->bpow($y);

    Compute $x ** $y.

    Please see the documentation in Math::BigInt for further details.

broot()
        $x->broot($n);

    Calculate the N'th root of $x.

bmodpow()
        $num->bmodpow($exp,$mod);           # modular exponentiation
                                            # ($num**$exp % $mod)

    Returns the value of $num taken to the power $exp in the modulus $mod using binary exponentiation. "bmodpow" is far superior to writing

        $num ** $exp % $mod

    because it is much faster - it reduces internal variables into the modulus whenever possible, so it operates on smaller numbers.

    "bmodpow" also supports negative exponents.

        bmodpow($num, -1, $mod)

    is exactly equivalent to

        bmodinv($num, $mod)

bmodinv()
        $x->bmodinv($mod);          # modular multiplicative inverse

    Returns the multiplicative inverse of $x modulo $mod. If

        $y = $x -> copy() -> bmodinv($mod)

    then $y is the number closest to zero, and with the same sign as $mod, satisfying

        ($x * $y) % $mod = 1 % $mod

    If $x and $y are non-zero, they must be relative primes, i.e., "bgcd($y, $mod)==1". '"NaN"' is returned when no modular multiplicative inverse exists.

blog()
        $x->blog($base, $accuracy);         # logarithm of x to the base $base

    If $base is not defined, Euler's number (e) is used:

        print $x->blog(undef, 100);         # log(x) to 100 digits

bexp()
        $x->bexp($accuracy);        # calculate e ** X

    Calculates two integers A and B so that A/B is equal to "e ** $x", where "e" is Euler's number.

    This method was added in v0.20 of Math::BigRat (May 2007).

    See also "blog()".

bnok()
    See "bnok()" in Math::BigInt.

bperm()
    See "bperm()" in Math::BigInt.

bfac()
        $x->bfac();

    Calculates the factorial of $x. For instance:

        print Math::BigRat->new('3/1')->bfac(), "\n";   # 1*2*3
        print Math::BigRat->new('5/1')->bfac(), "\n";   # 1*2*3*4*5

    Works currently only for integers.

band()
        $x->band($y);               # bitwise and

bior()
        $x->bior($y);               # bitwise inclusive or

bxor()
        $x->bxor($y);               # bitwise exclusive or

bnot()
        $x->bnot();                 # bitwise not (two's complement)

bfloor()
        $x->bfloor();

    Round $x towards minus infinity, i.e., set $x to the largest integer less than or equal to $x.

bceil()
        $x->bceil();

    Round $x towards plus infinity, i.e., set $x to the smallest integer greater than or equal to $x.

bint()
        $x->bint();

    Round $x towards zero.

bgcd()
        $x -> bgcd($y);             # GCD of $x and $y
        $x -> bgcd($y, $z, ...);    # GCD of $x, $y, $z, ...

    Returns the greatest common divisor (GCD), which is the number with the largest absolute value such that $x/$gcd, $y/$gcd, ... is an integer. For example, when the operands are 4/5 and 6/5, the GCD is 2/5. This is a generalisation of the ordinary GCD for integers. See "gcd()" in Math::BigInt.

digit()
        print Math::BigRat->new('123/1')->digit(1);     # 1
        print Math::BigRat->new('123/1')->digit(-1);    # 3

    Return the N'ths digit from X when X is an integer value.

length()
        $len = $x->length();

    Return the length of $x in digits for integer values.

parts()
        ($n, $d) = $x->parts();

    Return a list consisting of (signed) numerator and (unsigned) denominator as BigInts.

dparts()
    Returns the integer part and the fraction part.

fparts()
    Returns the smallest possible numerator and denominator so that the numerator divided by the denominator gives back the original value. For finite numbers, both values are integers. Mnemonic: fraction.

numerator()
        $n = $x->numerator();

    Returns a copy of the numerator (the part above the line) as signed BigInt.

denominator()
        $d = $x->denominator();

    Returns a copy of the denominator (the part under the line) as positive BigInt.

  String conversion methods

bstr()
        my $x = Math::BigRat->new('8/4');
        print $x->bstr(), "\n";             # prints 1/2

    Returns a string representing the number.

bnstr()
    See "bnstr()" in Math::BigInt.

bestr()
    See "bestr()" in Math::BigInt.

bdstr()
    See "bdstr()" in Math::BigInt.

to_bytes()
    See "to_bytes()" in Math::BigInt.

to_ieee754()
    See "to_ieee754()" in Math::BigFloat.

to_fp80()
    See "to_fp80()" in Math::BigFloat.

as_hex()
        $x = Math::BigRat->new('13');
        print $x->as_hex(), "\n";               # '0xd'

    Returns the BigRat as hexadecimal string. Works only for integers.

as_oct()
        $x = Math::BigRat->new('13');
        print $x->as_oct(), "\n";               # '015'

    Returns the BigRat as octal string. Works only for integers.

as_bin()
        $x = Math::BigRat->new('13');
        print $x->as_bin(), "\n";               # '0x1101'

    Returns the BigRat as binary string. Works only for integers.

numify()
        my $y = $x->numify();

    Returns the object as a scalar. This will lose some data if the object cannot be represented by a normal Perl scalar (integer or float), so use "as_int()" or "as_float()" instead.

    This routine is automatically used whenever a scalar is required:

        my $x = Math::BigRat->new('3/1');
        @array = (0, 1, 2, 3);
        $y = $array[$x];                # set $y to 3

config()
        Math::BigRat->config("trap_nan" => 1);      # set
        $accu = Math::BigRat->config("accuracy");   # get

    Set or get configuration parameter values. Read-only parameters are marked as RO. Read-write parameters are marked as RW. The following parameters are supported.

        Parameter       RO/RW   Description
                                Example
        ============================================================
        lib             RO      Name of the math backend library
                                Math::BigInt::Calc
        lib_version     RO      Version of the math backend library
                                0.30
        class           RO      The class of config you just called
                                Math::BigRat
        version         RO      version number of the class you used
                                0.10
        upgrade         RW      To which class numbers are upgraded
                                undef
        downgrade       RW      To which class numbers are downgraded
                                undef
        precision       RW      Global precision
                                undef
        accuracy        RW      Global accuracy
                                undef
        round_mode      RW      Global round mode
                                even
        div_scale       RW      Fallback accuracy for div, sqrt etc.
                                40
        trap_nan        RW      Trap NaNs
                                undef
        trap_inf        RW      Trap +inf/-inf
                                undef

NUMERIC LITERALS
After "use Math::BigRat ':constant'" all numeric literals in the given scope are converted to "Math::BigRat" objects. This conversion happens at compile time. Every non-integer is convert to a NaN.

For example,

    perl -MMath::BigRat=:constant -le 'print 2**150'

prints the exact value of "2**150". Note that without conversion of constants to objects the expression "2**150" is calculated using Perl scalars, which leads to an inaccurate result.

Please note that strings are not affected, so that

    use Math::BigRat qw/:constant/;

    $x = "1234567890123456789012345678901234567890"
            + "123456789123456789";

does give you what you expect. You need an explicit Math::BigRat->new() around at least one of the operands. You should also quote large constants to prevent loss of precision:

    use Math::BigRat;

    $x = Math::BigRat->new("1234567889123456789123456789123456789");

Without the quotes Perl first converts the large number to a floating point constant at compile time, and then converts the result to a Math::BigRat object at run time, which results in an inaccurate result.

  Hexadecimal, octal, and binary floating point literals
Perl (and this module) accepts hexadecimal, octal, and binary floating point literals, but use them with care with Perl versions before v5.32.0, because some versions of Perl silently give the wrong result. Below are some examples of different ways to write the number decimal 314.

Hexadecimal floating point literals:

    0x1.3ap+8         0X1.3AP+8
    0x1.3ap8          0X1.3AP8
    0x13a0p-4         0X13A0P-4

Octal floating point literals (with "0" prefix):

    01.164p+8         01.164P+8
    01.164p8          01.164P8
    011640p-4         011640P-4

Octal floating point literals (with "0o" prefix) (requires v5.34.0):

    0o1.164p+8        0O1.164P+8
    0o1.164p8         0O1.164P8
    0o11640p-4        0O11640P-4

Binary floating point literals:

    0b1.0011101p+8    0B1.0011101P+8
    0b1.0011101p8     0B1.0011101P8
    0b10011101000p-2  0B10011101000P-2

BUGS
Please report any bugs or feature requests to "bug-math-bigint at rt.cpan.org", or through the web interface at <https://rt.cpan.org/Ticket/Create.html?Queue=Math-BigInt> (requires login). We will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT
You can find documentation for this module with the perldoc command.

    perldoc Math::BigInt

You can also look for information at:

•   GitHub

    <https://github.com/pjacklam/p5-Math-BigInt>

•   RT: CPAN's request tracker

    <https://rt.cpan.org/Dist/Display.html?Name=Math-BigInt>

•   MetaCPAN

    <https://metacpan.org/release/Math-BigInt>

•   CPAN Testers Matrix

    <http://matrix.cpantesters.org/?dist=Math-BigInt>

LICENSE
This program is free software; you may redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO
Math::BigInt and Math::BigFloat as well as the backend libraries Math::BigInt::FastCalc, Math::BigInt::GMP, and Math::BigInt::Pari, Math::BigInt::GMPz, and Math::BigInt::BitVect.

The pragmas bigint, bigfloat, and bigrat might also be of interest. In addition there is the bignum pragma which does upgrading and downgrading.

AUTHORS

•   Tels <http://bloodgate.com/> 2001-2009.

•   Maintained by Peter John Acklam <pjacklam@gmail.com> 2011-