Net::DNS::Nameserver(3)

NAME
Net::DNS::Nameserver - DNS server class

SYNOPSIS
        use Net::DNS::Nameserver;

        my $nameserver = Net::DNS::Nameserver->new(
                        LocalAddr       => ['::1', '127.0.0.1'],
                        LocalPort       => 15353,
                        ZoneFile        => 'filename'
                        );

        my $nameserver = Net::DNS::Nameserver->new(
                        LocalAddr       => '10.1.2.3',
                        LocalPort       => 15353,
                        ReplyHandler    => \&reply_handler
                        );

        $nameserver->start_server($timeout);
        $nameserver->stop_server;

DESCRIPTION
Net::DNS::Nameserver offers a simple mechanism for instantiation of customised DNS server objects intended to provide test responses to queries emanating from a client resolver.

It is not, nor will it ever be, a general-purpose DNS nameserver implementation.

See "EXAMPLES" below for further details.

METHODS

  new
        $nameserver = Net::DNS::Nameserver->new(
                        LocalAddr       => ['::1', '127.0.0.1'],
                        LocalPort       => 15353,
                        ZoneFile        => "filename"
                        );

        $nameserver = Net::DNS::Nameserver->new(
                        LocalAddr       => '10.1.2.3',
                        LocalPort       => 15353,
                        ReplyHandler    => \&reply_handler,
                        Verbose         => 1,
                        Truncate        => 0
                        );

Instantiates a Net::DNS::Nameserver object. An exception is raised if the object could not be created.

Each instance is configured using the following optional arguments:

LocalAddr
    IP address on which to listen. Defaults to the local loopback address.

LocalPort
    Port on which to listen.

ZoneFile
    Name of file containing RRs accessed using the internal reply-handling subroutine.

ReplyHandler
    Reference to customised reply-handling subroutine.

NotifyHandler
    Reference to reply-handling subroutine for queries with opcode NOTIFY (RFC1996).

UpdateHandler
    Reference to reply-handling subroutine for queries with opcode UPDATE (RFC2136).

Verbose
    Report internal activity. Defaults to 0 (off).

Truncate
    Truncates UDP packets that are too big for the reply. Defaults to 1 (on).

The LocalAddr attribute may alternatively be specified as an array of IP addresses to listen to.

The ReplyHandler subroutine is passed the query name, query class, query type, peerhost, query record, and connection descriptor. It must either return the response code and references to the answer, authority, and additional sections of the response, or undef to leave the query unanswered. Common response codes are:

NOERROR
    No error

FORMERR
    Format error

SERVFAIL
    Server failure

NXDOMAIN
    Non-existent domain (name doesn't exist)

NOTIMP
    Not implemented

REFUSED
    Query refused

For advanced usage it may also contain a headermask containing an hashref with the settings for the "aa", "ra", and "ad" header bits. The argument is of the form:
    {ad => 1, aa => 0, ra => 1}

EDNS options may be specified in a similar manner using the optionmask:
    {$optioncode => $value, $optionname => $value}

See RFC1035 and IANA DNS parameters file for more information:

The nameserver will listen for both UDP and TCP connections. On linux and other Unix-like systems, unprivileged users are denied access to ports below 1024.

UDP reply truncation functionality was introduced in Net::DNS 0.66. The size limit is determined by the EDNS0 size advertised in the query, otherwise 512 is used. If you want to do packet truncation yourself you should set Truncate=>0 and truncate the reply packet in the code of the ReplyHandler.

  start_server
        $ns->start_server( <TIMEOUT_IN_SECONDS> );

Starts a server process for each of the specified UDP and TCP sockets which continuously responds to user connections.

The timeout parameter specifies the time the server is to remain active. If called with no parameter a default timeout of 10 minutes is applied.

  stop_server
        $ns->stop_server();

Terminates all server processes in an orderly fashion.

EXAMPLES

  Example 1: Test script with embedded nameserver
The following example is a self-contained test script which queries DNS zonefile data served by an embedded Net::DNS::Nameserver instance.

        use strict;
        use warnings;
        use Test::More;

        plan skip_all => 'Net::DNS::Nameserver not available'
                        unless eval { require Net::DNS::Nameserver }
                        and Net::DNS::Nameserver->can('start_server');
        plan tests => 2;

        my $resolver = Net::DNS::Resolver->new(
                        nameserver => ['::1', '127.0.0.1'],
                        port       => 15353
                        );

        my $ns = Net::DNS::Nameserver->new(
                        LocalAddr => [$resolver->nameserver],
                        LocalPort => $resolver->port,
                        Verbose   => 0,
                        ZoneFile  => \*DATA
                        ) or die "couldn't create nameserver object";

        $ns->start_server(10);

        my $reply = $resolver->send(qw(example.com SOA));
        is( ref($reply), 'Net::DNS::Packet', 'received reply packet' );
        my ($rr) = $reply->answer;
        is( $rr->type, 'SOA', 'answer contains SOA record' );

        $ns->stop_server();

        exit;

        __DATA__
        $ORIGIN example.com.
        @       IN SOA  mname rname 2023 2h 1h 2w 1h
        www     IN A    93.184.216.34

  Example 2: Free-standing customised DNS nameserver
The following example will listen on port 15353 and respond to all queries for A records with the IP address 10.1.2.3. All other queries will be
answered with NXDOMAIN.     Authority and additional sections are left empty.
The $peerhost variable catches the IP address of the peer host, so that additional filtering on a per-host basis may be applied.

        use strict;
        use warnings;
        use Net::DNS::Nameserver;

        sub reply_handler {
                my ( $qname, $qclass, $qtype, $peerhost, $query, $conn ) = @_;
                my ( $rcode, @ans, @auth, @add );

                print "Received query from $peerhost to " . $conn->{sockhost} . "\n";
                $query->print;

                if ( $qtype eq "A" && $qname eq "foo.example.com" ) {
                        my ( $ttl, $rdata ) = ( 3600, "10.1.2.3" );
                        my $rr = Net::DNS::RR->new("$qname $ttl $qclass $qtype $rdata");
                        push @ans, $rr;
                        $rcode = "NOERROR";
                } elsif ( $qname eq "foo.example.com" ) {
                        $rcode = "NOERROR";

                } else {
                        $rcode = "NXDOMAIN";
                }

                # mark the answer as authoritative (by setting the 'aa' flag)
                my $headermask = {aa => 1};

                # specify EDNS options  { option => value }
                my $optionmask = {};

                return ( $rcode, \@ans, \@auth, \@add, $headermask, $optionmask );
        }

        my $ns = Net::DNS::Nameserver->new(
                        LocalPort    => 15353,
                        ReplyHandler => \&reply_handler,
                        Verbose      => 1
                        ) or die "couldn't create nameserver object";

        $ns->start_server(60);

        exit;   # leaving nameserver processes running for 60 seconds

BUGS
Limitations in perl make it impossible to guarantee that replies to UDP queries from Net::DNS::Nameserver are sent from the IP-address to which the query was directed, the source address being chosen by the operating system based upon its notion of "closest address". This limitation is mitigated to some extent by creating a separate socket and subprocess for each IP address.

COPYRIGHT
Copyright (c)2000 Michael Fuhr.

Portions Copyright (c)2002-2004 Chris Reinhardt.

Portions Copyright (c)2005 Robert Martin-Legene.

Portions Copyright (c)2005-2009 O.M.Kolkman, RIPE NCC.

Portions Copyright (c)2017-2024 R.W.Franks.

All rights reserved.

LICENSE
Permission to use, copy, modify, and distribute this software and its documentation for any purpose and without fee is hereby granted, provided that the original copyright notices appear in all copies and that both copyright notice and this permission notice appear in supporting documentation, and that the name of the author not be used in advertising or publicity pertaining to distribution of the software without specific prior written permission.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

SEE ALSO
perl Net::DNS Net::DNS::Resolver Net::DNS::Packet Net::DNS::Update Net::DNS::Header Net::DNS::Question Net::DNS::RR